[feisty_meow.git] / huffware / huffotronic_scripts / fade_opacity_v3.7.txt


// huffware script: fade opacity, by fred huffhines, bsd-style license.
//
// when the object is touched, the opacity changes towards either
// totally transparent or totally opaque.  when touch stops, the
// changes stop.  the next time the objects is touched, the opacity
// changes in the opposite direction.
//
// this script is licensed by the GPL v3 which is documented at: http://www.gnu.org/licenses/gpl.html
// do not use it in objects without fully realizing you are implicitly accepting that license.
//

// modifiable parameters for the fading...

integer SWITCH_ONLY = FALSE;  // if true, does not fade, just switches on and off.

float pace_increment = 0.02;  // how much we change transparency in one timer call.

float timer_interval = 0.1;  // how frequently timer is hit.

float highest_opacity = 1.0;  // the most visible an object can be.

float lowest_opacity = 0.0;  // the least visible an object can be.

//integer FADE_TARGETS = LINK_THIS;  // affect only the prim this script is in.
integer FADE_TARGETS = LINK_SET;  // fade the entire object, all prims.
//integer FADE_TARGETS = 3;  // fade just the second prim, not the root.

// globals...

float global_direction = -1.0;
    // tells us whether we are making the object more transparent
    // (positive numbers) or less transparent (negative numbers).

integer last_update;
    // unix time of last mention of the opacity.

// displays the current opaqueness of the object.
show_opacity()
{
    float opacity = llGetAlpha(ALL_SIDES) / (float)llGetNumberOfSides() * 100.0;
    string message = (string)((integer)opacity) + "% opacity";
    llSetText(message, <.2, .8, .6>, 1.0);
    // whisper the setting if we haven't in a bit.
    if (llGetUnixTime() - last_update >= 2) {
        llWhisper(0, message);
        last_update = llGetUnixTime();
    }
}

// get rid of the text label.
show_nothing() { llSetText("", <0.0, 0.0, 0.0>, 0.0); }

//////////////

//////////////
// huffware script: auto-retire, by fred huffhines, version 2.5.
// distributed under BSD-like license.
//   !!  keep in mind that this code must be *copied* into another
//   !!  script that you wish to add auto-retirement capability to.
// when a script has auto_retire in it, it can be dropped into an
// object and the most recent version of the script will destroy
// all older versions.
//
// the version numbers are embedded into the script names themselves.
// the notation for versions uses a letter 'v', followed by two numbers
// in the form "major.minor".
// major and minor versions are implicitly considered as a floating point
// number that increases with each newer version of the script.  thus,
// "hazmap v0.1" might be the first script in the "hazmap" script continuum,
// and "hazmap v3.2" is a more recent version.
//
// example usage of the auto-retirement script:
//     default {
//         state_entry() {
//            auto_retire();  // make sure newest addition is only version of script.
//        }
//     }
// this script is partly based on the self-upgrading scripts from markov brodsky
// and jippen faddoul.
//////////////
auto_retire() {
    string self = llGetScriptName();  // the name of this script.
    list split = compute_basename_and_version(self);
    if (llGetListLength(split) != 2) return;  // nothing to do for this script.
    string basename = llList2String(split, 0);  // script name with no version attached.
    string version_string = llList2String(split, 1);  // the version found.
    integer posn;
    // find any scripts that match the basename.  they are variants of this script.
    for (posn = llGetInventoryNumber(INVENTORY_SCRIPT) - 1; posn >= 0; posn--) {
//log_it("invpo=" + (string)posn);
        string curr_script = llGetInventoryName(INVENTORY_SCRIPT, posn);
        if ( (curr_script != self) && (llSubStringIndex(curr_script, basename) == 0) ) {
            // found a basic match at least.
            list inv_split = compute_basename_and_version(curr_script);
            if (llGetListLength(inv_split) == 2) {
                // see if this script is more ancient.
                string inv_version_string = llList2String(inv_split, 1);  // the version found.
                // must make sure that the retiring script is completely the identical basename;
                // just matching in the front doesn't make it a relative.
                if ( (llList2String(inv_split, 0) == basename)
                    && ((float)inv_version_string < (float)version_string) ) {
                    // remove script with same name from inventory that has inferior version.
                    llRemoveInventory(curr_script);
                }
            }
        }
    }
}
//
// separates the base script name and version number.  used by auto_retire.
list compute_basename_and_version(string to_chop_up)
{
    // minimum script name is 2 characters plus a version.
    integer space_v_posn;
    // find the last useful space and 'v' combo.
    for (space_v_posn = llStringLength(to_chop_up) - 3;
        (space_v_posn >= 2) && (llGetSubString(to_chop_up, space_v_posn, space_v_posn + 1) != " v");
        space_v_posn--) {
        // look for space and v but do nothing else.
//log_it("pos=" + (string)space_v_posn);
    }
    if (space_v_posn < 2) return [];  // no space found.
//log_it("space v@" + (string)space_v_posn);
    // now we zoom through the stuff after our beloved v character and find any evil
    // space characters, which are most likely from SL having found a duplicate item
    // name and not so helpfully renamed it for us.
    integer indy;
    for (indy = llStringLength(to_chop_up) - 1; indy > space_v_posn; indy--) {
//log_it("indy=" + (string)space_v_posn);
        if (llGetSubString(to_chop_up, indy, indy) == " ") {
            // found one; zap it.  since we're going backwards we don't need to
            // adjust the loop at all.
            to_chop_up = llDeleteSubString(to_chop_up, indy, indy);
//log_it("saw case of previously redundant item, aieee.  flattened: " + to_chop_up);
        }
    }
    string full_suffix = llGetSubString(to_chop_up, space_v_posn, -1);
    // ditch the space character for our numerical check.
    string chop_suffix = llGetSubString(full_suffix, 1, llStringLength(full_suffix) - 1);
    // strip out a 'v' if there is one.
    if (llGetSubString(chop_suffix, 0, 0) == "v")
        chop_suffix = llGetSubString(chop_suffix, 1, llStringLength(chop_suffix) - 1);
    // if valid floating point number and greater than zero, that works for our version.
    string basename = to_chop_up;  // script name with no version attached.
    if ((float)chop_suffix > 0.0) {
        // this is a big success right here.
        basename = llGetSubString(to_chop_up, 0, -llStringLength(full_suffix) - 1);
        return [ basename, chop_suffix ];
    }
    // seems like we found nothing useful.
    return [];
}
//
//////////////

default
{
    state_entry() { if (llSubStringIndex(llGetObjectName(),  "huffotronic") < 0) state real_default; }
    on_rez(integer parm) { state rerun; }
}
state rerun { state_entry() { state default; } }

state real_default
{
    state_entry() {
        auto_retire();
        show_nothing();  // clean out any existing text.
        last_update = llGetUnixTime();
    }

    touch_start(integer total_number) {
        global_direction *= -1.0;  // change the direction for next time.
        if (SWITCH_ONLY) {
            if (global_direction > 0.0)
                llSetLinkAlpha(FADE_TARGETS, highest_opacity, ALL_SIDES);
            else
                llSetLinkAlpha(FADE_TARGETS, lowest_opacity, ALL_SIDES);
        } else {
            // do the full fade routine.  start the timer to change the
            // opacity while the avatar keeps touching the object.
            llSetTimerEvent(timer_interval);
        }
    }

    touch_end(integer total_number) {
        llSetTimerEvent(0);  // stop the timer.
        show_nothing();  // clear the text out.
    }

    timer() {
        float current = llGetAlpha(ALL_SIDES) / (float)llGetNumberOfSides()
            + pace_increment * global_direction;
        if (current > highest_opacity) { current = highest_opacity; }
        if (current < lowest_opacity) { current = lowest_opacity; }
        // change transparency on all links, including root prim.
        llSetLinkAlpha(FADE_TARGETS, current, ALL_SIDES);
        show_opacity();
    }
}