scripts/archival/shared_snarfer.pl

   1 #!/usr/bin/perl
   2
   3 ###############################################################################
   4 #                                                                             #
   5 #  Name   : shared_snarfer                                                    #
   6 #  Author : Chris Koeritz                                                     #
   7 #  Rights : Copyright (C) 1996-$now by Author                                 #
   8 #                                                                             #
   9 #  Purpose:                                                                   #
  10 #                                                                             #
  11 #    A shared library collection for "snarfing up" archives.  This uses the   #
  12 #  compressed tar format for files ending in ".snarf" to store collections    #
  13 #  of files, folders, hierarchies and so forth.                               #
  14 #                                                                             #
  15 ###############################################################################
  16 #  This program is free software; you can redistribute it and/or modify it    #
  17 #  under the terms of the GNU General Public License as published by the Free #
  18 #  Software Foundation; either version 2 of the License or (at your option)   #
  19 #  any later version.  See: "http://www.gruntose.com/Info/GNU/GPL.html" for a #
  20 #  version of the License.  Please send any updates to "fred@gruntose.com".   #
  21 ###############################################################################
  22
  23 require "filename_helper.pl";
  24 require "inc_num.pl";
  25
  26 use Cwd;
  27 use Sys::Hostname;
  28 use File::Which;
  29 use Env qw(FEISTY_MEOW_SCRIPTS TMP);
  30
  31 $null_log = "/dev/null";
  32
  33 $TMP =~ s/\\/\//g;  # fix the temp variable for ms-winders.
  34
  35 # defines an array of problematic entries we were told to deal with.
  36 @missing_log = ();
  37
  38 # these files are considered unimportant and won't be included in the archive.
  39 @junk_file_list = ("*~", "*.$$$", "3rdparty", "*.aps", "*.bak", "binaries",
  40     "*.bsc", "*.cgl", "*.csm", "CVS", "Debug", "*.dll", "*.err", "*.exe",
  41     "generated_*", "*.git", "*.glb", "inprogress", "ipch", "*.llm",
  42     "*.log", "*.lnk",
  43     "makefile.fw*", "*.mbt", "*.mrt", "*.ncb", "*.o", "obj", "*.obj",
  44     "octalforty.Wizardby", "*.obr", "*.opt", "packages",
  45     "*.pch", "*.pdb", "*.plg", "*.r$p", "*.rcs", "Release",
  46     "*.res", "*.RES", "*.rws", "*.sbr", "*.scc", "*.spx", "*.stackdump",
  47     "Steam",
  48     "*.sdf", "*.suo", ".svn", "*.sym", "*.td", "*.tds", "*.tdw", "*.tlb",
  49     "*.trw", "*.tmp", "*.tr", "*.user", "*_version.h", "*_version.rc",
  50     "*.vspscc", "waste", "zeitgeist");
  51 #print "junk list=@junk_file_list\n";
  52 @excludes = ();
  53 for (local($i) = 0; $i < scalar(@junk_file_list); $i++) {
  54   push(@excludes, "--exclude=$junk_file_list[$i]");
  55 }
  56 #print "excludes list=@excludes\n";
  57
  58 # generic versions work on sane OSes.
  59 $find_tool = which('find');
  60 $tar_tool = which('tar');
  61 #print "find tool: $find_tool\n";
  62 #print "tar tool: $tar_tool\n";
  63
  64 if ( ! -f "$find_tool" || ! -f "$tar_tool" ) {
  65   print "Could not locate either tar or find tools for this platform.\n";
  66   exit 3;
  67 }
  68
  69 # this is somewhat ugly, but it sets up a global variable called
  70 # "original_path" so we remember where we started.
  71 sub initialize_snarfer {
  72   $original_path = cwd();
  73   $original_path =~ s/\\/\//g;
  74 }
  75
  76 # returns the current hostname, but without any domain included.
  77 sub short_hostname {
  78   local($temphost) = hostname();
  79 #&hostname();
  80   $temphost =~ s/([^.]*)\..*/\1/;
  81   return &lower($temphost);
  82 }
  83
  84 # takes the base name and creates the full snarf prefix name, which includes
  85 # a timestamp and hostname.
  86 sub snarf_prefix {
  87   local($base) = @_;
  88
  89 #hmmm: extract this shared code to new function (also in safedel)
  90   $date_tool = "date";
  91   local($date_part) = `$date_tool +%Y-%m-%d-%H%M`;
  92   while ($date_part =~ /[\r\n]$/) { chop $date_part; }
  93
  94   local($host) = &short_hostname();
  95   while ($host =~ /[\r\n]$/) { chop $host; }
  96   $base = $base . "_" . $host . "_" . $date_part;
  97   return $base;
  98 }
  99
 100 # returns the name of the file to create based on the prefix and the
 101 # current archive number.
 102 sub snarf_name {
 103   local($prefix, $number) = @_;
 104   local($path) = &canonicalize($original_path);
 105   local($target_file) = $path . '/' . $prefix . "_" . $number . ".tar";
 106   return $target_file;
 107 }
 108
 109 # finishes up on the archive file.
 110 sub finalize_snarf {
 111   local($filename) = @_;
 112 #print "finalizing now on filename $filename\n";
 113   local($outcome) = 0xff & system "gzip", $filename;
 114   if ($outcome) { die("failure to finalize"); }
 115
 116   if (scalar(@missing_log)) {
 117     print "The following files or directories were missing:\n";
 118     print "@missing_log\n";
 119   }
 120 }
 121
 122 # fixes the directory passed in, if required.  this is only needed for
 123 # dos-like operating systems, where there are drives to worry about and where
 124 # cygwin refuses to store the full path for an absolute pathname in the
 125 # archive.  instead of letting it store partial paths, we change to the top
 126 # of the drive and scoop up the files using a relative path.
 127 sub chdir_to_top {
 128   local($directory) = @_;
 129   if ( (substr($directory, 0, 2) eq "//")
 130       && (substr($directory, 3, 1) eq "/") ) {
 131 #print "into special case\n";
 132     # it was originally a dos path, so now we must do some directory changing
 133     # magic to get the paths to work right.
 134     local($drive) = substr($directory, 0, 4);  # get just drive letter biz.
 135 #print "going to change to $drive\n";
 136     chdir($drive);
 137 #print "cwd now=" . cwd() . "\n";
 138     $directory = substr($directory, 4);  # rip off absolutist path.
 139 #print "using dir now as $directory\n";
 140     if (length($directory) == 0) {
 141 #print "caught zero length dir, patching to dot now.\n";
 142       $directory = ".";
 143     }
 144   }
 145   return $directory;
 146 }
 147
 148 # snarfer scoops up some files in a directory.
 149 sub snarfer {
 150   local($prefix, $number, $root, $subdir, @extra_flags) = @_;
 151 #print "prefix=$prefix, num=$number, root=$root, subdir=$subdir, extra=@extra_flags\n";
 152
 153   $root = &chdir_to_top($root);
 154
 155   local($target_file) = &snarf_name($prefix, $number);
 156
 157   $random_num = (rand() * 1000000) % 1000000;
 158   $temp_file = `mktemp "$TMP/zz_snarf_tmp.XXXXXX"`;
 159   chop($temp_file);
 160
 161   if (! -d $root . "/" . $subdir) {
 162     local($base) = &basename($root . "/" . $subdir);
 163 #print "adding to missing in snarfer A: $base\n";
 164     push(@missing_log, $base);
 165     return 0;
 166   }
 167   local($currdir) = cwd();
 168   chdir($root);
 169
 170   local($outcome) = 0;
 171   my @lines = qx( $find_tool "$subdir" @extra_flags "-type" "f" );
 172 #  if ( ($! != 0) || ($? != 0) ) {
 173 #    die("failure to find files in $subdir");
 174 #  }
 175
 176   open TEMPY_OUT, ">>$temp_file" or die "cannot open $temp_file";
 177   foreach (@lines) { print TEMPY_OUT "$_"; }
 178   close TEMPY_OUT;
 179
 180   if (-s $temp_file == 0) {
 181     local($base) = &basename($root . "/" . $subdir);
 182 #print "adding to missing in snarfer B: $base\n";
 183     push(@missing_log, $base);
 184   }
 185
 186   local($outcome) = 0xff & system $tar_tool,
 187       "-rf", &canonicalize($target_file), @excludes,
 188       "--files-from=" . &canonicalize($temp_file);
 189   if ($outcome) {
 190     unlink($temp_file);
 191     die("failure to archive");
 192   }
 193   # clean up temporaries.
 194   unlink($temp_file);
 195   # change back to previous directory.
 196   chdir($currdir);
 197 }
 198
 199 # snarf_file_list is like snarfer but expects a file pattern at the end rather
 200 # than a directory name.
 201 sub snarf_file_list {
 202   local($prefix, $number, $root, $file_pattern, @extra_flags) = @_;
 203
 204 #print "prefix=$prefix, num=$number, root=$root, file_pattern=$file_pattern, extra=@extra_flags\n";
 205
 206   $root = &chdir_to_top($root);
 207
 208   local($target_file) = &snarf_name($prefix, $number);
 209
 210   local($currdir) = cwd();
 211 #print "got root as: '$root'\n";
 212   chdir("$root");
 213
 214   local(@files) = &glob_list($file_pattern);
 215   if (!scalar(@files)) {
 216     local($base) = $root . "/" . $file_pattern;
 217     $base =~ s/\/\//\//g;
 218 #print "adding to missing in snarf_file_list: $base\n";
 219     push(@missing_log, $base);
 220   }
 221
 222   foreach $i (@files) {
 223     if ($i =~ /^\.\//) {
 224       $i = substr $i, 2, length($i) - 2;
 225     }
 226     local($outcome) = 0xff & system $tar_tool,
 227 #"--directory=" . "$root",
 228         @extra_flags, "-rf", &canonicalize($target_file), @excludes, $i;
 229     if ($outcome) { die("failure to archive"); }
 230   }
 231   chdir("$currdir");
 232 }
 233
 234 # backup some specific files.
 235 sub backup_files {
 236   local($prefix, $number, $root, $subdir, @files) = @_;
 237 #print "backup_files: ref=$prefix, num=$number, subdir=$subdir, list of files=@files\n";
 238   foreach $i (@files) {
 239     local($new_path) = $subdir . "/" . $i;
 240     if ($subdir eq ".") { $new_path = "$i"; }
 241     &snarf_file_list($prefix, $number, $root, $new_path);
 242   }
 243 }
 244
 245 # backup some specific directories.
 246 sub backup_directories {
 247   local($prefix, $number, $root, $subdir, @dirs) = @_;
 248 #print "backup_directories: ref=$prefix, num=$number, root=$root, subdir=$subdir, list of dirs=@dirs.\n";
 249   foreach $i (@dirs) {
 250     local($path_to_use) = $subdir . "/" . $i;
 251     if ($i eq ".") {
 252       $path_to_use = $subdir;
 253     }
 254     &snarfer($prefix, $number, $root, $path_to_use, ("-maxdepth", "1"));
 255   }
 256 }
 257
 258 # removes items from the file that match a pattern.
 259 sub remove_from_backup {
 260   local($prefix, $number, $pattern) = @_;
 261 #print "remove_from_backup: pref=$prefix, num=$number, patt=$pattern,\n";
 262   local($target_file) = &snarf_name($prefix, $number);
 263
 264   open(TARPROC, "$tar_tool --delete -f " . &canonicalize($target_file)
 265       . " \"$pattern\" 2>$null_log |");
 266   <TARPROC>;
 267 }
 268
 269 # recursively scoops up a directory hierarchy.
 270 sub backup_hierarchy {
 271   local($prefix, $number, $root, $filepart) = @_;
 272 #print "backup_hierarchy: pref=$prefix, num=$number, root=$root, filepart=$filepart\n";
 273   local(@locus_temp) = &glob_list($root);
 274   local($save_root) = $root;
 275   local($root) = $locus_temp[0];
 276   if (!length($root)) {
 277     local($base) = $save_root . "/" . $filepart;
 278 #print "adding to missing in backup_hierarchy A: $base\n";
 279     push(@missing_log, $base);
 280     return;
 281   }
 282   local($new_pattern) = "$root/$filepart";
 283   if ($root =~ /\/$/) { $new_pattern = "$root$filepart"; }
 284   local(@mod_locus) = &glob_list($new_pattern);
 285   if (!scalar(@mod_locus)) {
 286     local($base) = &basename($root . "/" . $filepart);
 287 #print "adding to missing in backup_hierarchy B: $base\n";
 288     push(@missing_log, $base);
 289   } else {
 290     foreach $i (@mod_locus) {
 291       local($new_locus) = $root;
 292       local $offset_len = length($root) + 1;
 293       local $char_len = length($i) - length($root) - 1;
 294       # make sure we don't double slashes up if one's already there.
 295       if ($root =~ /\/$/) { $offset_len--; $char_len++; }
 296       local($extra_portion) = substr $i, $offset_len, $char_len;
 297       if (!length($extra_portion)) {
 298         # well, in this case, there's nothing left of the extra part after
 299         # the root.  we'll push the last component of the root down into
 300         # the extra part so there's actually something to traverse.
 301         $new_locus = &dirname($root);
 302         $extra_portion = &basename($root);
 303       }
 304       &snarfer($prefix, $number, $new_locus, $extra_portion, ());
 305     }
 306   }
 307 }
 308
 309 # recursively scoop up a list of directory hierarchies.
 310 sub backup_hierarchies {
 311   local($prefix, $number, $root, @dirs) = @_;
 312 #  print "backup_hierarchy: pref=$prefix, num=$number, root=$root,\n";
 313 #  print "list of dirs=@dirs.\n";
 314   foreach $i (@dirs) {
 315     &backup_hierarchy($prefix, $number, $root, $i);
 316   }
 317 }
 318
 319 # grab up all the files in a directory (second parm) that are named matching
 320 # a simple text pattern (third parm).  if there is a fourth parameter, it is
 321 # used as an extra directory component after the main directory.
 322 sub snarf_by_pattern {
 323   local($prefix, $dir, $pattern, $extra_component) = @_;
 324   local($had_extra) = length($extra_component) != 0;
 325 #print "snarf by pattern, dir = $dir, patt = $pattern, extra = $extra_component\n";
 326   if ($had_extra) {
 327     $dir = "$dir/$extra_component";
 328   }
 329   @dir_contents = &glob_list("$dir/*$pattern*");
 330 #print "dir contents: @dir_contents\n";
 331
 332   if (!scalar(@dir_contents)) {
 333     print "no '$pattern' directores were backed up in $dir.\n";
 334   }
 335
 336   foreach $item (@dir_contents) {
 337     if ( ($item =~ /$pattern.*snarf/) || ($item =~ /$pattern.*tar/) ) { next; }
 338     if ( ! -d "$item" ) { next; }
 339 #print "now really planning to backup hier of $item\n";
 340     # normal backup had no extra component.
 341     local $upper_dir = &dirname($item);
 342     local $dir_plus_base = &basename($item);
 343     # if we did have an extra component, we do this a bit differently.
 344     if ($had_extra) {
 345       $upper_dir = &dirname( &dirname($item) );
 346       $dir_plus_base = &basename( &dirname($item) ) . "/" . &basename($item);
 347     }
 348 #print "using upper=$upper_dir and dir+base=$dir_plus_base\n";
 349     &backup_hierarchy($prefix, $number, $upper_dir, $dir_plus_base);
 350   }
 351 }
 352
 353 # gets the number out of the file specified by a basename.  the number file
 354 # is assumed to be stored in the TMP directory and to have an extension of
 355 # ".num".
 356 sub retrieve_number {
 357   local($number_prefix) = @_;
 358   # get number from the file specified and increment it for the next use.
 359   local($NUMBER_FILE) = $TMP."/$number_prefix.num";
 360   local($number) = &get_number($NUMBER_FILE);
 361   &next_number($NUMBER_FILE);
 362   return $number;
 363 }
 364
 365 # takes a name to use as the basename for a number file, and stores the
 366 # file into the archive specified.
 367 sub backup_number {
 368   local($number_prefix, $snarf_prefix, $number) = @_;
 369 #print "backup_number: parms are: numpref=$number_prefix, archpref=$snarf_prefix, num=$number.\n";
 370   local($target_file) = $original_path ."/". $snarf_prefix . "_" . $number . ".tar";
 371   local($number_file) = $number_prefix . ".num";
 372
 373   local($currdir) = cwd();
 374   chdir($TMP);
 375
 376   local($outcome) = 0xff & system $tar_tool, "-cf",
 377       &canonicalize($target_file), &canonicalize($number_file);
 378   if ($outcome) { die("failure to archive"); }
 379
 380   local($prefix_file) = "prefix.bac";
 381   open(NUM_PREFIX, ">" . $prefix_file);
 382   print NUM_PREFIX $number_prefix;
 383   close(NUM_PREFIX);
 384
 385   $outcome = 0xff & system $tar_tool, "-rf",
 386       &canonicalize($target_file), &canonicalize($prefix_file);
 387   if ($outcome) { die("failure to archive"); }
 388   unlink($prefix_file);
 389   chdir($currdir);
 390 }
 391
 392 # takes a prefix for the number file and a filename where it can be found.
 393 # the current number in the temporary directory is compared against the file,
 394 # and the new number's used if it's greater.
 395 sub restore_number {
 396   local($number_prefix, $number_file) = @_;
 397 #print "restore num has numpref $number_prefix and numfile $number_file\n";
 398   local($comparison_file) = "$TMP" . "/" . $number_prefix . ".num";
 399   local($number) = &get_number($number_file);
 400   local($old_number) = &get_number($comparison_file);
 401   if ($number > $old_number) {
 402     &store_number($number, $comparison_file);
 403   }
 404   unlink($number_file);
 405 }
 406
 407 # ensures that the special restoration program is used on the archives by
 408 # renaming their extension.
 409 sub rename_archive {
 410   local($filename) = @_;
 411 #print "rename_archive: file=$filename\n";
 412   &finalize_snarf($filename);
 413   local(@pieces) = split(/\.[^.]*$/, $filename, 3);
 414   local($just_dir_and_base) = $pieces[0];
 415   local($new_name) = $just_dir_and_base . '.snarf';
 416   rename($filename . ".gz", $new_name)
 417       || die("could not rename $filename to $new_name.");
 418 }
 419
 420 # undoes a snarfed up archive and pulls out the number.
 421 sub restore_archive {
 422   local($filename) = &canonicalize(&remove_trailing_slashes(@_));
 423   local(@split_name) = &split_filename($filename);
 424   if ($#split_name < 1) {
 425     print "The name \"$filename\" could not be parsed for restoration.\n";
 426     exit 1;
 427   }
 428   # get the basename of the file.
 429   local(@pieces) = split(/\.[^.]*$/, @split_name[1], 2);
 430   # we don't want the extension.
 431   local($just_dir_and_base) = $split_name[0] . $pieces[0];
 432   # now just get the basename without a directory.
 433   local(@name_components) = split(/\//, $just_dir_and_base);
 434   local($basename) = $name_components[$#name_components];
 435   local($new_dir_name) = 'snarf_' . $basename;
 436
 437   local($currdir) = cwd();
 438
 439   if (!chdir($new_dir_name)) {
 440     mkdir($new_dir_name, 0777)
 441         || die("could not create directory $new_dir_name.");
 442     if (!chdir($new_dir_name)) {
 443       die("could not change to directory $new_dir_name.");
 444     }
 445   }
 446
 447   # patch a relative path name to reflect the fact that we're now underneath
 448   # the directory where we were.
 449   if (! ($filename =~ /^\//)
 450       && ! ($filename =~ /^.:/) ) {
 451     $filename = "../" . $filename;
 452   }
 453
 454   local($outcome) = 0xff & system $tar_tool, "-xzf",
 455       &canonicalize($filename);
 456   if ($outcome) { die("failure to undo archive"); }
 457
 458   local($outcome) =
 459       0xff & system "bash", "$FEISTY_MEOW_SCRIPTS/security/normal_perm.sh", ".";
 460   if ($outcome) { die("failure to normalize permissions"); }
 461
 462   # remove any links that might have crept in; these can cause mischief.
 463   local($outcome) = 0xff & system("$find_tool . -type l -exec rm {} ';'");
 464
 465   # read the name of the prefix file.
 466   local($prefix_file) = "prefix.bac";
 467   open(NUM_PREFIX, "<" . $prefix_file);
 468   local($number_prefix) = <NUM_PREFIX>;
 469   close(NUM_PREFIX);
 470
 471   &restore_number($number_prefix, $number_prefix . ".num");
 472   unlink($prefix_file);
 473
 474   chdir($currdir);
 475 }
 476
 477 1;
 478